<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Test2::Event::Plan;
use strict;
use warnings;

our $VERSION = '1.302190';


BEGIN { require Test2::Event; our @ISA = qw(Test2::Event) }
use Test2::Util::HashBase qw{max directive reason};

use Carp qw/confess/;

my %ALLOWED = (
    'SKIP'    =&gt; 1,
    'NO PLAN' =&gt; 1,
);

sub init {
    if ($_[0]-&gt;{+DIRECTIVE}) {
        $_[0]-&gt;{+DIRECTIVE} = 'SKIP'    if $_[0]-&gt;{+DIRECTIVE} eq 'skip_all';
        $_[0]-&gt;{+DIRECTIVE} = 'NO PLAN' if $_[0]-&gt;{+DIRECTIVE} eq 'no_plan';

        confess "'" . $_[0]-&gt;{+DIRECTIVE} . "' is not a valid plan directive"
            unless $ALLOWED{$_[0]-&gt;{+DIRECTIVE}};
    }
    else {
        confess "Cannot have a reason without a directive!"
            if defined $_[0]-&gt;{+REASON};

        confess "No number of tests specified"
            unless defined $_[0]-&gt;{+MAX};

        confess "Plan test count '" . $_[0]-&gt;{+MAX}  . "' does not appear to be a valid positive integer"
            unless $_[0]-&gt;{+MAX} =~ m/^\d+$/;

        $_[0]-&gt;{+DIRECTIVE} = '';
    }
}

sub sets_plan {
    my $self = shift;
    return (
        $self-&gt;{+MAX},
        $self-&gt;{+DIRECTIVE},
        $self-&gt;{+REASON},
    );
}

sub terminate {
    my $self = shift;
    # On skip_all we want to terminate the hub
    return 0 if $self-&gt;{+DIRECTIVE} &amp;&amp; $self-&gt;{+DIRECTIVE} eq 'SKIP';
    return undef;
}

sub summary {
    my $self = shift;
    my $max = $self-&gt;{+MAX};
    my $directive = $self-&gt;{+DIRECTIVE};
    my $reason = $self-&gt;{+REASON};

    return "Plan is $max assertions"
        if $max || !$directive;

    return "Plan is '$directive', $reason"
        if $reason;

    return "Plan is '$directive'";
}

sub facet_data {
    my $self = shift;

    my $out = $self-&gt;common_facet_data;

    $out-&gt;{control}-&gt;{terminate} = $self-&gt;{+DIRECTIVE} eq 'SKIP' ? 0 : undef
        unless defined $out-&gt;{control}-&gt;{terminate};

    $out-&gt;{plan} = {count =&gt; $self-&gt;{+MAX}};
    $out-&gt;{plan}-&gt;{details} = $self-&gt;{+REASON} if defined $self-&gt;{+REASON};

    if (my $dir = $self-&gt;{+DIRECTIVE}) {
        $out-&gt;{plan}-&gt;{skip} = 1 if $dir eq 'SKIP';
        $out-&gt;{plan}-&gt;{none} = 1 if $dir eq 'NO PLAN';
    }

    return $out;
}


1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test2::Event::Plan - The event of a plan

=head1 DESCRIPTION

Plan events are fired off whenever a plan is declared, done testing is called,
or a subtext completes.

=head1 SYNOPSIS

    use Test2::API qw/context/;
    use Test2::Event::Plan;

    my $ctx = context();

    # Plan for 10 tests to run
    my $event = $ctx-&gt;plan(10);

    # Plan to skip all tests (will exit 0)
    $ctx-&gt;plan(0, skip_all =&gt; "These tests need to be skipped");

=head1 ACCESSORS

=over 4

=item $num = $plan-&gt;max

Get the number of expected tests

=item $dir = $plan-&gt;directive

Get the directive (such as TODO, skip_all, or no_plan).

=item $reason = $plan-&gt;reason

Get the reason for the directive.

=back

=head1 SOURCE

The source code repository for Test2 can be found at
F&lt;http://github.com/Test-More/test-more/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2020 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See F&lt;http://dev.perl.org/licenses/&gt;

=cut
</pre></body></html>